jro_apps/redmine Commit - r2056:131b15fc7a0d

Fix access to Repository Parent Path (FORBIDEN instead of AUTH_REQUIRED)....

Liwiusz Ociepa -

r2056:131b15fc7a0d swistak

parent child

Context file:

r2056:131b15fc7a0d

Collapse all files

extra/svn/Redmine.pm +7 -3

              package Apache::Authn::Redmine;
              =head1 Apache::Authn::Redmine
              Redmine - a mod_perl module to authenticate webdav subversion users
              against redmine database
              =head1 SYNOPSIS
              This module allow anonymous users to browse public project and
              registred users to browse and commit their project. Authentication is
              done against the redmine database or the LDAP configured in redmine.
              This method is far simpler than the one with pam_* and works with all
              database without an hassle but you need to have apache/mod_perl on the
              svn server.
              =head1 INSTALLATION
              For this to automagically work, you need to have a recent reposman.rb
              (after r860) and if you already use reposman, read the last section to
              migrate.
              Sorry ruby users but you need some perl modules, at least mod_perl2,
              DBI and DBD::mysql (or the DBD driver for you database as it should
              work on allmost all databases).
              On debian/ubuntu you must do :
                aptitude install libapache-dbi-perl libapache2-mod-perl2 libdbd-mysql-perl
              If your Redmine users use LDAP authentication, you will also need
              Authen::Simple::LDAP (and IO::Socket::SSL if LDAPS is used):
                aptitude install libauthen-simple-ldap-perl libio-socket-ssl-perl
              =head1 CONFIGURATION
                 ## This module has to be in your perl path
                 ## eg:  /usr/lib/perl5/Apache/Authn/Redmine.pm
                 PerlLoadModule Apache::Authn::Redmine
                 <Location /svn>
                   DAV svn
                   SVNParentPath "/var/svn"
                   AuthType Basic
                   AuthName redmine
                   Require valid-user
                   PerlAccessHandler Apache::Authn::Redmine::access_handler
                   PerlAuthenHandler Apache::Authn::Redmine::authen_handler
                   ## for mysql
                   RedmineDSN "DBI:mysql:database=databasename;host=my.db.server"
                   ## for postgres
                   # RedmineDSN "DBI:Pg:dbname=databasename;host=my.db.server"
                   RedmineDbUser "redmine"
                   RedmineDbPass "password"
                   ## Optional where clause (fulltext search would be slow and
                   ## database dependant).
                   # RedmineDbWhereClause "and members.role_id IN (1,2)"
                   ## Configuration for memcached
                   # RedmineMemcacheServers "127.0.0.1:112211"
                   # RedmineMemcacheExpirySec "60"
                   # RedmineMemcacheNamespace "RedmineCreds:"
                </Location>
              To be able to browse repository inside redmine, you must add something
              like that :
                 <Location /svn-private>
                   DAV svn
                   SVNParentPath "/var/svn"
                   Order deny,allow
                   Deny from all
                   # only allow reading orders
                   <Limit GET PROPFIND OPTIONS REPORT>
                     Allow from redmine.server.ip
                   </Limit>
                 </Location>
              and you will have to use this reposman.rb command line to create repository :
                reposman.rb --redmine my.redmine.server --svn-dir /var/svn --owner www-data -u http://svn.server/svn-private/
              =head1 MIGRATION FROM OLDER RELEASES
              If you use an older reposman.rb (r860 or before), you need to change
              rights on repositories to allow the apache user to read and write
              S<them :>
                sudo chown -R www-data /var/svn/*
                sudo chmod -R u+w /var/svn/*
              And you need to upgrade at least reposman.rb (after r860).
              =cut
              use strict;
              use warnings FATAL => 'all', NONFATAL => 'redefine';
              use DBI;
              use Digest::SHA1;
              # optional module for LDAP authentication
              my $CanUseLDAPAuth = eval("use Authen::Simple::LDAP; 1");
              my $CanUseMemcached = eval("use Cache::Memcached; 1");
              use Apache2::Module;
              use Apache2::Access;
              use Apache2::ServerRec qw();
              use Apache2::RequestRec qw();
              use Apache2::RequestUtil qw();
              use Apache2::Const qw(:common :override :cmd_how);
              # use Apache2::Directive qw();
              my @directives = (
                {
                  name => 'RedmineDSN',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                  errmsg => 'Dsn in format used by Perl DBI. eg: "DBI:Pg:dbname=databasename;host=my.db.server"',
                },
                {
                  name => 'RedmineDbUser',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
                {
                  name => 'RedmineDbPass',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
                {
                  name => 'RedmineDbWhereClause',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
                {
                  name => 'RedmineMemcacheServers',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
                {
                  name => 'RedmineMemcacheExpirySec',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
                {
                  name => 'RedmineMemcacheNamespace',
                  req_override => OR_AUTHCFG,
                  args_how => TAKE1,
                },
              );
              sub RedmineDSN {
                my ($self, $parms, $arg) = @_;
                $self->{RedmineDSN} = $arg;
                my $query = "SELECT
                               hashed_password, auth_source_id
                            FROM members, projects, users
                            WHERE
                              projects.id=members.project_id
                              AND users.id=members.user_id
                              AND users.status=1
                              AND login=?
                              AND identifier=? ";
                $self->{RedmineQuery} = trim($query);
              }
              sub RedmineDbUser { set_val('RedmineDbUser', @_); }
              sub RedmineDbPass { set_val('RedmineDbPass', @_); }
              sub RedmineDbWhereClause {
                my ($self, $parms, $arg) = @_;
                $self->{RedmineQuery} = trim($self->{RedmineQuery}.($arg ? $arg : "")." ");
              }
              sub RedmineMemcacheServers {
                my ($self, $parms, $arg) = @_;
                if ($arg && $CanUseMemcached) {
                  $self->{RedmineMemcached} = new Cache::Memcached {
                    'servers' => [ $arg, ],
                    'debug' => 0,
                  };
                  $self->{RedmineMemcache} = 1;
                }
              }
              sub RedmineMemcacheExpirySec { set_val('RedmineMemcacheExpirySec', @_); }
              sub RedmineMemcacheNamespace {
                my ($self, $parms, $arg) = @_;
                if ($self->{RedmineMemcache}) {
                  # Undocumented feature of Cache::Memcached, please don't kill me
                  $self->{RedmineMemcached}->{namespace} = $arg;
                  $self->{RedmineMemcached}->{namespace_len} = length $self->{RedmineMemcached}->{namespace};
                }
              }
              sub trim {
                my $string = shift;
                $string =~ s/\s{2,}/ /g;
                return $string;
              }
              sub set_val {
                my ($key, $self, $parms, $arg) = @_;
                $self->{$key} = $arg;
              }
              Apache2::Module::add(__PACKAGE__, \@directives);
              my %read_only_methods = map { $_ => 1 } qw/GET PROPFIND REPORT OPTIONS/;
              sub access_handler {
                my $r = shift;
                unless ($r->some_auth_required) {
                    $r->log_reason("No authentication has been configured");
                    return FORBIDDEN;
                }
                my $method = $r->method;
                return OK if defined $read_only_methods{$method};
                my $project_id = get_project_identifier($r);
                $r->set_handlers(PerlAuthenHandler => [\&OK])
                    if is_public_project($project_id, $r);
                return OK
              }
              sub authen_handler {
                my $r = shift;
                my ($res, $redmine_pass) =  $r->get_basic_auth_pw();
                return $res unless $res == OK;
-               if (is_member($r->user, $redmine_pass, $r)) {
+               my $project_id  = get_project_identifier($r);
+               if (!$project_id) {
+                 return FORBIDDEN;
+               }
+               if (is_member($r->user, $redmine_pass, $r, $project_id)) {
                    return OK;
                } else {
                    $r->note_auth_failure();
                    return AUTH_REQUIRED;
                }
              }
              sub is_public_project {
                  my $project_id = shift;
                  my $r = shift;
                  my $cfg = Apache2::Module::get_config(__PACKAGE__, $r->server, $r->per_dir_config);
                  if ($cfg->{RedmineMemcache}) {
                    return 1 if ($cfg->{RedmineMemcached}->get($project_id));
                  }
                  my $dbh = connect_database($r);
                  my $sth = $dbh->prepare(
                      "SELECT * FROM projects WHERE projects.identifier=? and projects.is_public=true;"
                  );
                  $sth->execute($project_id);
                  my $ret = $sth->fetchrow_array ? 1 : 0;
                  $sth->finish();
                  $dbh->disconnect();
                  if ($cfg->{RedmineMemcache}) {
                    if ($cfg->{RedmineMemcacheExpirySec}) {
                      $cfg->{RedmineMemcached}->set($project_id, $ret, $cfg->{RedmineMemcacheExpirySec});
                    } else {
                      $cfg->{RedmineMemcached}->set($project_id, $ret);
                    }
                  }
                  $ret;
              }
              # perhaps we should use repository right (other read right) to check public access.
              # it could be faster BUT it doesn't work for the moment.
              # sub is_public_project_by_file {
              #     my $project_id = shift;
              #     my $r = shift;
              #     my $tree = Apache2::Directive::conftree();
              #     my $node = $tree->lookup('Location', $r->location);
              #     my $hash = $node->as_hash;
              #     my $svnparentpath = $hash->{SVNParentPath};
              #     my $repos_path = $svnparentpath . "/" . $project_id;
              #     return 1 if (stat($repos_path))[2] & 00007;
              # }
              sub is_member {
                my $redmine_user = shift;
                my $redmine_pass = shift;
                my $r = shift;
+               my $project_id = shift;
                my $dbh         = connect_database($r);
-               my $project_id  = get_project_identifier($r);
                my $pass_digest = Digest::SHA1::sha1_hex($redmine_pass);
                my $cfg = Apache2::Module::get_config(__PACKAGE__, $r->server, $r->per_dir_config);
                my $usrprojpass;
                if ($cfg->{RedmineMemcache}) {
                  $usrprojpass = $cfg->{RedmineMemcached}->get($redmine_user.":".$project_id);
                  return 1 if (defined $usrprojpass and ($usrprojpass eq $pass_digest));
                }
                my $query = $cfg->{RedmineQuery};
                my $sth = $dbh->prepare($query);
                $sth->execute($redmine_user, $project_id);
                my $ret;
                while (my @row = $sth->fetchrow_array) {
                    unless ($row[1]) {
                        if ($row[0] eq $pass_digest) {
                            $ret = 1;
                            last;
                        }
                    } elsif ($CanUseLDAPAuth) {
                        my $sthldap = $dbh->prepare(
                            "SELECT host,port,tls,account,account_password,base_dn,attr_login from auth_sources WHERE id = ?;"
                        );
                        $sthldap->execute($row[1]);
                        while (my @rowldap = $sthldap->fetchrow_array) {
                          my $ldap = Authen::Simple::LDAP->new(
                              host    =>      ($rowldap[2] == 1 || $rowldap[2] eq "t") ? "ldaps://$rowldap[0]" : $rowldap[0],
                              port    =>      $rowldap[1],
                              basedn  =>      $rowldap[5],
                              binddn  =>      $rowldap[3] ? $rowldap[3] : "",
                              bindpw  =>      $rowldap[4] ? $rowldap[4] : "",
                              filter  =>      "(".$rowldap[6]."=%s)"
                          );
                          $ret = 1 if ($ldap->authenticate($redmine_user, $redmine_pass));
                        }
                        $sthldap->finish();
                    }
                }
                $sth->finish();
                $dbh->disconnect();
                if ($cfg->{RedmineMemcache} and $ret) {
                  if ($cfg->{RedmineMemcacheExpirySec}) {
                    $cfg->{RedmineMemcached}->set($redmine_user.":".$project_id, $pass_digest, $cfg->{RedmineMemcacheExpirySec});
                  } else {
                    $cfg->{RedmineMemcached}->set($redmine_user.":".$project_id, $pass_digest);
                  }
                }
                $ret;
              }
              sub get_project_identifier {
                  my $r = shift;
                  my $location = $r->location;
                  my ($identifier) = $r->uri =~ m{$location/*([^/]+)};
-                 $identifier ? $identifier : " ";
+                 $identifier;
              }
              sub connect_database {
                  my $r = shift;
                  my $cfg = Apache2::Module::get_config(__PACKAGE__, $r->server, $r->per_dir_config);
                  return DBI->connect($cfg->{RedmineDSN}, $cfg->{RedmineDbUser}, $cfg->{RedmineDbPass});
              }
 ;

General Comments 0

Write
Preview

You need to be logged in to leave comments. Login now

No TODOs yet

	Site-wide shortcuts
/	Use quick search box
g h	Goto home page
g g	Goto my private gists page
g G	Goto my public gists page
g 0-9	Goto bookmarked items from 0-9
n r	New repository page
n g	New gist page

	Repositories
g s	Goto summary page
g c	Goto changelog page
g f	Goto files page
g F	Goto files page with file search activated
g p	Goto pull requests page
g o	Goto repository settings
g O	Goto repository access permissions settings
t s	Toggle sidebar on some pages